sperimentare

esercitazioni con turbopascal v.(3), 5-7
file.pas richiamati con turbo pascal v.5
si forniscono alcune immagini e listato.pas:
possibile copiarlo,incollarlo su notes ,
salvarlo come file.pas, richiamarlo con
turbo pascal v.5  o 7 presente su PC
(dovrebbe funzionare, anche se datato ..1990..2000)

soluzione triangoli (anche rettangoli) con teorema del coseno

http://informascienze.altervista.org/algebraturbo/algebraturbo.htm

http://informascienze.altervista.org/algebraturbo/triangolo.htm

program triango;
(* funzioni trigonometriche di angoli inseriti in gradi INTERI*)
(* risoluzione triangoli qualsiasi E RETTANGOLI *)
uses crt;
var tipo:integer;n:string;
   
    a,b,c,alfa,beta,gamma,alfar,betar,gammar:real;
    seno,coseno,tangente:real;
    c1,beta1,gamma1,betar1,gammar1,r:real;
 
  FUNCTION radiante(x:real):real;
  begin
   radiante:=x*pi/180;
   end;
  
    FUNCTION gradi(x:real):real;
  begin
   gradi:=x*180/pi;
   end;
 
  FUNCTION tan(x:real):real;
  begin
   tan:=sin(x)/cos(x);
  end;
    
 
  function arcsin(x:real):real;
  const k=1e-15;
  begin
   if x<-1 + k then arcsin:=-Pi/2;
   if x>1-k then arcsin:=Pi/2;
   if (x>-1+k) and (x<1-k) then arcsin:=arctan(x/sqrt(1-x*x));
   end;

function arccos(x:real):real;
  const k=1e-15;
  begin
   if (x<k) and (x>-k) then arccos:=Pi/2;
   if x>k then arccos:=arctan(sqrt(1-x*x)/x);
   if x<-k then arccos:=Pi+arctan(sqrt(1-x*x)/x);
   end;

  procedure pro1; (* NOTI TRE LATI *)
begin
 clrscr;
 writeln('applicare teorema del coseno');
 write('valore lato a   =');readln(a);
 write('valore lato b   =');readln(b);
 write('valore lato c   =');readln(c);
 writeln;
 writeln('calcolo cos(alfa) = (b^2 + c^2 - 2bc) / 2bc ');
 coseno:=((b*b+c*c-a*a)/(2*b*c));
 writeln('calcolo arco corrispondente a coseno :arccos(coseno)');
 alfar:=arccos(coseno);
 coseno:=((a*a+c*c-b*b)/(2*a*c));
 betar:=arccos(coseno);
 coseno:=((b*b+a*a-c*c)/(2*b*a));
 gammar:=arccos(coseno);
 writeln('trasformo radianti in gradi e stampo i due valori');
 writeln('ripeto le stesse operazioni per beta e gamma');
 writeln;
 writeln('angolo alfa  =',alfar:8:2,gradi(alfar):8:2);
 writeln('angolo beta  =',betar:8:2,gradi(betar):8:2);
 writeln('angolo gamma =',gammar:8:2,gradi(gammar):8:2);
 end;

 procedure pro2; (* LATO E ANGOLI ADIACENTI *)
begin
 clrscr;
 writeln('applicare legge dei seni');
 write('valore lato   a      =');readln(a);
 write('valore angolo beta  =');readln(beta);
 write('valore angolo gamma =');readln(gamma);
 writeln;
 alfa:=180- (beta+gamma);
 writeln('calcolo angolo opposto al lato a con 180-beta-gamma');
 writeln('trasformo angoli da gradi in radianti');
 writeln('calcolo lato b = a*sin(beta)/sin(alfa)');
 b:=a*sin(radiante(beta))/sin(radiante(alfa));
 c:=a*sin(radiante(gamma))/sin(radiante(alfa));
 writeln('ripeto operazioni per lato c e stampa risultati');
 writeln;
 writeln('angolo alfa        =',alfa:8:2);
 writeln('lato b             =',b:8:2);
 writeln('lato c             =',c:8:2);
 
 end;
 
 procedure pro3; (* LATO E DUE ANGOLI:opposto e adiacente  *)
begin
 clrscr;
 writeln('applicare legge dei seni');
 write('valore lato a               =');readln(a);
 write('valore angolo opposto alfa  =');readln(alfa);
 write('valore angolo adiacente beta=');readln(beta);
 writeln;
 writeln('calcolo angolo gamma con 180 - alfa - beta ');
 gamma:=180- (beta+alfa);
 writeln('trasformo angoli da gradi in radianti');
 writeln('calcolo lato b = a*sin(beta)/sin(alfa)');
 b:=a*sin(radiante(beta))/sin(radiante(alfa));
 c:=a*sin(radiante(gamma))/sin(radiante(alfa));
 writeln('ripeto operazioni per lato c e stampo risultati');
 writeln;
 writeln('angolo gamma       =',gamma:8:2);
 writeln('lato b             =',b:8:2);
 writeln('lato c             =',c:8:2);
 
 end;

  procedure pro4; (* NOTI due lati e angolo tra essi compreso *)
begin
 clrscr;
 writeln('applicare teorema coseno ');
 write('valore lato a         =');readln(a);
 write('valore lato b         =');readln(b);
 write('valore angolo gamma   =');readln(gamma);
 writeln;
 writeln('trasformare angolo da gradi in radianti ');
 gammar:=radiante(gamma);
 writeln('calcolare lato c^2 = b^2 + a^2 - 2ab*cos(gamma)');
 c:=b*b+a*a-2*a*b*cos(gammar);
 writeln('estrarre radice quadrata di c ');
 c:=sqrt(c);
 writeln('calcolare arco corrispondente a seno con arcsin(seno)');
 writeln('trasformare valori da radianti in gradi e stampare risultato');
 WRITELN;
 seno:=(b*sin(gammar)/c);
 betar:=arcsin(seno);
 alfar:=pi-betar-gammar;
 writeln('valore lato c       =',c:8:2);
 writeln('valore angolo alfa  =',gradi(alfar):8:2);
 writeln('valore angolo beta  =',gradi(betar):8:2);
 end;

   procedure pro5; (* NOTI due lati e angolo opposto a un lato *)
begin
 clrscr;
 write('valore lato a                     =');readln(a);
 write('valore lato b                     =');readln(b);
 write('valore angolo ALFA opposto ad a   =');readln(alfa);
 WRITELN;
 alfar:=radiante(alfa);
 r:=b*sin(alfar);
 if ((alfar<pi/2) and (a<r)) or ((alfar>=pi/2) and (a<b)) then
  begin
   writeln('nessuna soluzione')
   end
   else
   begin
    betar:=arcsin(b*sin(alfar)/a);
    beta:=gradi(betar);
    gammar:=pi-alfar-betar;
    gamma:=gradi(gammar);
    c:=a*sin(gammar)/sin(alfar);
    writeln('angolo gamma compreso tra lati a,b =',gamma:8:2);
    writeln('angolo beta                        =',beta:8:2);
    writeln('terzo lato c                       =',c:8:2);
    writeln;
     if a>b then
      begin
       writeln('unica soluzione');
       writeln('-----------------------------------------');
       end
      
       else
       begin
        betar1:=pi-betar;
        beta1:=gradi(betar1);
        gammar1:=pi - alfar-betar1;
        gamma1:=gradi(gammar1);       
        c1:=a*sin(gammar1)/sin(alfar);
        writeln('angolo gamma compreso tra lati a,b  =',gamma1:8:2);
        writeln('angolo  beta                        =',beta1:8:2);
        writeln('terzo lato c                        =',c1:8:2);
        writeln;
        writeln('due soluzioni');
        end;
        end;
        end;
       
   procedure pro6; (* NOTI I CATETI B,C *)
begin
 clrscr;
 write('valore cateto b   =');readln(b);
 write('valore cateto c   =');readln(c);
 writeln;
 tangente:=b/c; (* tg(beta) *)
 betar:=arctan(tangente);
 a:=b/sin(betar);
 beta:=gradi(betar);
 gamma:=90-beta;
  writeln;
 writeln('ipotenusa    =',a:8:2);
 writeln('angolo beta  =',beta:8:2);
 writeln('angolo gamma =',gamma:8:2);
 writeln;
 end;
 

   procedure pro7; (* NOTI IPOTENUSA A e CATETO B *)
begin
 clrscr;
 write('valore ipotenusa  =');readln(a);
 write('valore cateto b   =');readln(b);
 writeln;
 seno:=b/a ;   (* seno(beta) *)
 betar:=arcsin(seno);
 gammar:=pi/2 -betar;
 c:=a*sin(gammar);
 beta:=gradi(betar);
 gamma:=gradi(gammar);
  writeln;
 writeln('cateto c     =',c:8:2);
 writeln('angolo beta  =',beta:8:2);
 writeln('angolo gamma =',gamma:8:2);
 writeln;
 end;

   procedure pro8; (* NOTI CATETO B e angolo BETA *)
begin
 clrscr;
 write('valore cateto b      =');readln(b);
 write('valore angolo beta   =');readln(beta);
 writeln;
 gamma:=90-beta;
 gammar:=radiante(gamma);
 c:=b*tan(gammar);
 betar:=radiante(beta);
 a:=b/sin(betar);
  writeln;
 writeln('cateto c     =',c:8:2);
 writeln('ipotenusa a  =',a:8:2);
 writeln('angolo gamma =',gamma:8:2);
 writeln;
 end;

   procedure pro9; (* NOTI IPOTENUSA A e angolo BETA *)
begin
 clrscr;
 write('valore ipotenusa a   =');readln(a);
 write('valore angolo beta   =');readln(beta);
 writeln;
 gamma:=90-beta;
 betar:=radiante(beta);
 b:=a*sin(betar);
 c:=a*cos(betar);
  writeln;
 writeln('cateto c     =',c:8:2);
 writeln('cateto b     =',b:8:2);
 writeln('angolo gamma =',gamma:8:2);
 writeln;
 end;

 procedure azione;
 begin
 clrscr;
 writeln('1...noti i tre lati:A,B,C ');
 writeln('calcolo angoli alfa,beta,gamma');
 writeln;
 writeln('2...noto lato A e angoli adiacenti BETA,GAMMA');
 writeln('calcolo alfa,B,C');
 writeln;
 writeln('3...noto lato A e angoli:opposto ALFA e adiacente BETA');
 writeln('calcolo gamma,B,C');
 writeln;
 writeln('4...noti due lati A,B e angolo compreso tra essi GAMMA');
 writeln('calcolo C,alfa,beta');
 writeln;
 writeln('5...noti due lati A,B e angolo opposto ALFA ');
 writeln('calcolo C,beta,gamma');
 writeln;
 writeln('TRIANGOLI RETTANGOLI');
 writeln('6...noti due cateti B,C calcolare ipotenusa,beta,gamma');
 writeln('7...noti ipotenusa A e cateto B:calcolare cateto C,beta,gamma');
 writeln('8...noti cateto B e angolo BETA:calcolo A,C,gamma');
 writeln('9...noti ipotenusa A e angolo BETA:calcolo B,C,gamma');
 writeln('0...per finire');
 writeln('indica tipo triangolo da risolvere:');
 readln(tipo);
 
 if tipo=1 then pro1;
 if tipo=2 then pro2;
 if tipo=3 then pro3;
 if tipo=4 then pro4;
 if tipo=5 then pro5;
 if tipo=6 then pro6;
 if tipo=7 then pro7;
 if tipo=8 then pro8;
 if tipo=9 then pro9;
 write('per altra prova scrivi 1,per finire 2 ');readln(n);
 if n='1' then azione;
 
 end;
 
 
 begin
 clrscr;azione;end.